Jump to content
Search In
  • More options...
Find results that contain...
Find results in...
  • Announcement

    Sorry for the recent downtime. Still much to do but we have the site updated, secure and back online.  Expect more changes.

  • 0

Batch file pour renomer les .cue


orphen92

Question

Hello,

 

j'ai eut besoin de faire un batch file pour faire en sorte d'utiliser facilement des bin cue europée pour le systeme psx avec la liste officielle Qui propose les jeux US.

Dans l'idée c'est relativement relou

- Recuperer le pack de roms europée

- Renommer l'ensemble des fichier 7z europpée pour leurs donner le nom americain

- Extraire les 7z donner aux fichiers .cue le nom US

- Recompresser en 7Z pour economier de la place.

 

Aussi j'ai fait un fichier batch qui permet de faire ceci.

- Pour chaque 7z d'un dossier

- Recuperation du nom du fichier (le nom us du jeu)

- Extraction dans un dossier temporaire

- Renommage du fichier cue avec le nom US

- Recompression de l'archive avec le bon nom

- Deplacement dans le dossier des roms

- Suppression du dossier temporaire

 

Il faut changer les Path avec vos propre URl et mettre le fichier 7z.exe au meme endroit que le batch

@echo off & cls
setlocal EnableDelayedExpansion
 
set current_path=%~dp0
set current_path_modified=%current_path:~0,-1%
set "TempDir=E:\hubic\Roms\Sony PlayStation\a traiter\1-A decompresser\Temp"
set "FinalDir=E:\hubic\Roms\Sony PlayStation"
 
if not exist "%current_path_modified%\7z.exe" (
    echo 7z.exe est introuvable dans %current_path_modified%
    echo Extinction du script dans 10 secondes.
    timeout 10
    exit
)

if not exist "!TempDir!" md "!TempDir!"
if not exist "!FinalDir!" md "!FinalDir!"
 
for /F "delims=" %%I in ('dir /b *.7z') do (

    set "Current7zFileName=%%~nI"
    set "Current7zFileExtension=%%~xI"
    set "Current7zFullName=!Current7zFileName!!Current7zFileExtension!"
    echo Fichier en cours de traitement: !Current7zFileName!
    echo Extraction de !Current7zFullName! dans !TempDir!
    7z e "!Current7zFullName!" -o"!TempDir!" * -r

    for /F "delims=" %%J in ('dir /b "!TempDir!"\*.cue') do (
        echo Renommage de %%J en !Current7zFileName!%%~xJ
        move "!TempDir!\%%J" "!TempDir!\!Current7zFileName!%%~xJ"

    )

    echo On cree l'archive !Current7zFileName!.7z et on la deplace dans !FinalDir!
    7z a -t7z "!TempDir!\!Current7zFileName!.7z" "!TempDir!\*"
    move "!TempDir!\!Current7zFileName!.7z" "!FinalDir!"
    echo On nettoie le dossier temporaire
    rd /S /Q "!TempDir!"
)
 
pause
exit

Ah oui prennez ce code et mettez le dans un fichier notepad avec une extention .bat

 

Orphen

Link to comment
Share on other sites

2 answers to this question

Recommended Posts

Salut,

T'aurais pas plus vite fait de récupérer le xml français? Ce serait plus cohérent. Là, tu te retrouves avec des roms européennes renommées en US? En tout cas, merci pour le partage de ton batch, ça interessera peut être quelqu'un ;)

Link to comment
Share on other sites

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...