HyperSpin Settings Randomly Erased

[jpv108]

Hey all,

Question... has anyone's HyperHQ setting.ini file been erased randomly? This has now happened to me three times over the past couple months. If so, am I doing something to cause this?

Example: Just now for instance... I turned on my arcade cab and everything booted up to Windows XP as usual. I double click the HyperSpin icon and it goes right to my main wheel (no intro - the first sign something is up) with none of my customized controls working. I back out of HyperSpin and double click HyperHQ... all settings are erased. Nothing is in the boxes for controls... all blank. The path to HyperLaunch is back to default so I get an error when trying to load games via HyperSpin.

I have now backed up my settings.ini file and just do a quick copy to get everything back to normal.

Just wondering if anyone else is running into this. Gets kind of annoying but not to the breaking point yet.

[rfancella]

Hey all,

Question... has anyone's HyperHQ setting.ini file been erased randomly? This has now happened to me three times over the past couple months. If so, am I doing something to cause this?

Example: Just now for instance... I turned on my arcade cab and everything booted up to Windows XP as usual. I double click the HyperSpin icon and it goes right to my main wheel (no intro - the first sign something is up) with none of my customized controls working. I back out of HyperSpin and double click HyperHQ... all settings are erased. Nothing is in the boxes for controls... all blank. The path to HyperLaunch is back to default so I get an error when trying to load games via HyperSpin.

I have now backed up my settings.ini file and just do a quick copy to get everything back to normal.

Just wondering if anyone else is running into this. Gets kind of annoying but not to the breaking point yet.

I wrote a small batch file that backs up all your HyperHQ & HyperLaunch ini files, database files, HyperLaunch modules and HyperLaunch Profiles. You place the batch file in your HyperSpin directory and double click it. It will keep 5 sets of backups. So anytime you make a change, run the batch.

Here is the batch file:

@ECHO OFF
SETLOCAL

rmdir /s /q Backups\HSBackup6
Echo Backup #6 Deleted
move Backups\HSBackup5 Backups\HSBackup6
Echo Moved Backup 5 to 6
move Backups\HSBackup4 Backups\HSBackup5
Echo Moved Backup 4 to 5
move Backups\HSBackup3 Backups\HSBackup4
Echo Moved Backup 3 to 4
move Backups\HSBackup2 Backups\HSBackup3
Echo Moved Backup 2 to 3
move Backups\HSBackup1 Backups\HSBackup2
Echo Moved Backup 1 to 2
mkdir Backups\HSBackup1

SET _source=Settings
SET _dest=Backups\HSBackup1\Settings

SET _options=/R:0 /W:0 /LOG:Backups\HSBackup1\MyHSBackup.txt /NFL /NDL
:: /R:n :: number of Retries
:: /W:n :: Wait time between retries
:: /LOG :: Output log file
:: /NFL :: No file logging
:: /NDL :: No dir logging

CALL :RUN
Echo HS Settings Done

SET _options=/R:0 /W:0 /LOG+:Backups\HSBackup1\MyHSBackup.txt /NFL /NDL
:: /R:n :: number of Retries
:: /W:n :: Wait time between retries
:: /LOG :: Output log file
:: /NFL :: No file logging
:: /NDL :: No dir logging

SET _source=Databases
SET _dest=Backups\HSBackup1\Databases
CALL :RUN
Echo HS Databases Done

SET _source=HyperLaunch\Settings
SET _dest=Backups\HSBackup1\HyperLaunch\Settings
CALL :RUN
Echo HL Settings Done

SET _source=HyperLaunch\Modules
SET _dest=Backups\HSBackup1\HyperLaunch\Modules
CALL :RUN
Echo HL Modules Done

SET _source=HyperLaunch\Profiles
SET _dest=Backups\HSBackup1\HyperLaunch\Profiles
CALL :RUN
Echo HL Profiles Done

SET _source=HyperLaunch\Data
SET _dest=Backups\HSBackup1\HyperLaunch\Data
CALL :RUN
Echo HL Data Done

GOTO :EOF


:RUN

SET _what=/COPYALL /B /SEC /MIR
:: /COPYALL :: COPY ALL file info
:: /B :: copy files in Backup mode. 
:: /SEC :: copy files with SECurity
:: /MIR :: MIRror a directory tree 


ROBOCOPY %_source% %_dest% %_what% %_options%



:EOF

Just create a new txt document and paste this into it. Rename it to Backup.cmd and run it.

Thanks,

Ron

[jpv108]

I'll give it a try... Thank Ron! Much appreciated!

[relic]

your a genious rfan so many useful scripts you make for us big thanks from relic

[rfancella]

your a genious rfan so many useful scripts you make for us big thanks from relic

Thank you Relic!

Thanks,

Ron