Super Mario Crossover

[gamesmame]

I can not go get the 1.1 version in full screen that says the new version, I was very sad at not being able to run fullscreen version that has the ninja gaiden! really wanted to work in fullscreen and I not find anyone to help us get a place in fullscreen script or anything ...

[zerojay]

As I said before, I will release something that will allow full screen. I'm also going to take a run at Rokko Chan because it doesn't allow playing from anywhere but its website, so we're going to see what we can do about that.

[yuskis1]

im trying to get flash games to run too. ive converted them from flv to exe but dont know how to get exe games to launch through hyperlaunch in hyperspin. playing with the keyboard sucks. help me!

[baddeolv]

im trying to get flash games to run too. ive converted them from flv to exe but dont know how to get exe games to launch through hyperlaunch in hyperspin. playing with the keyboard sucks. help me!

make shortcuts to your .exe files, set your rom ext to .LNK in hyperHQ

point hyperHQ to the shortcut you created

[Mr Black Arm]

I warped to 4-1 with Simon. Ryu is pretty fun too. Would defintely make a cool rom.

[mastershoes]

man zerojay, i ran into this game a long time ago, and was dyin' to find a version coverted into a rom... if you can pull this off, you'll be my hero man!... Now if we could just get someone to make the Full House StreetFighter Game, lol. All would be good

[zerojay]

It's impossible to convert it to a ROM, that won't ever be possible. I'll post my stuff later today.

[zerojay]

Got a far better version of my updated script, so here it is.

Flash Games.ahk:

;----------------------------------------------------------------------------
; Flash Games
; Flash Player Projector v10.3.183.7
; by zerojay, based heavily on djvj's original
; 1.3.3
;
; This version of the Flash Player Projector script will attempt to play your games at full screen,
; however if the Flash game doesn't allow fullscreen or doesn't scale, you can set a resolution to
; switch to on a game-by-game basis in the Settings.ini file. Upon launching, the script will use QRes
; to switch to a resolution you have selected in the Settings.ini file for that game.
;
; Notes:
; If you want a game to go fullscreen, define it in the Setting.ini
; If you forget to define your game in the ini, a section for it will be created for you when you first run it.
; 
;----------------------------------------------------------------------------

settingsFile := checkFile2(A_WorkingDir . "\Modules\" . systemName . "\Settings.ini")

resChangerPath := checkFile2(A_WorkingDir . "\Modules\" . systemName . "\QRes.exe")

FadeInStart()

IniRead, loadingScreen, %settingsFile%, Settings, LoadingScreen
IniRead, fullscreen, %settingsFile%, %romName%, Fullscreen
IniRead, horizontalResolution, %settingsFile%, %romName%, HorizontalResolution
IniRead, verticalResolution, %settingsFile%, %romName%, VerticalResolution

RestoreScreenX := A_ScreenWidth
RestoreScreenY := A_ScreenHeight


If ( fullscreen = "ERROR" )
CreateSection(settingsFile, romName)

7z(romPath, romName, romExtension, 7zExtractDir)

If ( fullscreen != "true" )
WinMinimizeAll

SetControlDelay, 50
Run, %executable%, %emuPath%
WinWait, AHK_class ShockwaveFlash
Send, ^o ; Open File
WinWait, AHK_class #32770
ControlSetText, Edit1, %romPath%%romName%%romExtension%, AHK_class #32770
ControlSend, Button1, {Enter}, AHK_class #32770

WinSet, Style, -0xC00000, AHK_class ShockwaveFlash ; Removes the titlebar of the game window
WinSet, Style, -0x40000, AHK_class ShockwaveFlash ; Removes the border of the game window
DllCall("SetMenu", uint, WinActive( "A" ), uint, 0) ; Removes the MenuBar

; Go Fullscreen
If ( fullscreen = "true" ) {
	Sleep, 500
	Send, ^f
	Sleep, 500
} Else
	Center("AHK_class ShockwaveFlash")

FadeInExit()
Run, %resChangerPath% -x:%horizontalResolution% -y:%verticalResolution%
Process, WaitClose, %executable%


7zCleanUp()

If ( fullscreen != "true" )
WinMinimizeAllUndo

FadeOutExit()



WinActivate, Hyperspin

Run, %resChangerPath% -x:%RestoreScreenX% -y:%RestoreScreenY%

WinMaximize, HyperSpin

ExitApp

Center(title) {
	WinGetPos, x, y, width, height, %title%
	x := ( A_ScreenWidth / 2 ) - ( width / 2 )
	y := ( A_ScreenHeight / 2 ) - ( height / 2 )
	WinMove, %title%, , x, y
}

CreateSection(file,sectionname) {
	FileAppend,
	(
		`n[%sectionname%]`nFullscreen = false`n
	), %file%
}

CheckFile2(file) {
	IfNotExist, %file%
	{
		MsgBox, 48, Error, Cannot find %file%`nCreating a default Settings.ini for you. Open it and add your games or on first run they will be created for you., 8
		FileAppend,
		(
			[settings]`nLoadingScreen = true`n`n
		), %file%
		ExitApp
	}
	Return %file%
}

CloseProcess:
Run, %resChangerPath% -x:%RestoreScreenX% -y:%RestoreScreenY% -depth=32 
FadeOutStart()

WinClose, AHK_class ShockwaveFlash

Return

Settings.ini:

[settings]
LoadingScreen = true

[Abobo's Big Adventure]
Fullscreen = true
HorizontalResolution = 1920
VerticalResolution = 1080

[super Mario Crossover]
Fullscreen = true
HorizontalResolution = 640
VerticalResolution = 480

[N]
Fullscreen = true
HorizontalResolution = 800
VerticalResolution = 600

Grab QRes.exe from here and place it side-by-side with the Settings.ini and Flash Games.ahk files in the Flash Games module folder. For games that won't fullscreen on their own, add the game to the list and assign it a resolution to switch to.

Let me know how it goes. By the way, this fixed my issue with N not properly restoring after being quit from. I suspected it had something to do with the program I was using to switch the resolutions. Everything's working for me so far now.

[jeepguy81]

Great job zeroJ. been playing off and on for bout 2hrs so far and have run into no probs so far.

[Lailoken]

Run, %executable%, %emuPath%
WinWait, AHK_class ShockwaveFlash
Send, ^o ; Open File

Adobe Flash Player runs flash files through a command line (i.e. Run, "C:\FlashPlayer.exe" "C:\Roms\Abobo's Big Adventure.swf"); It has no switches, though, as far as I could find. It also goes fullscreen by sending Ctrl+F, so you shouldn't need all the title bar/border removing.

I noticed your script is for version 10. Version 11 is out and you can get it here: http://www.adobe.com/support/flashplayer/downloads.html. It shouldn't affect your script, but I know that some newer games won't play on 10.

[zerojay]

Run, %executable%, %emuPath%
WinWait, AHK_class ShockwaveFlash
Send, ^o ; Open File

Adobe Flash Player runs flash files through a command line (i.e. Run, "C:\FlashPlayer.exe" "C:\Roms\Abobo's Big Adventure.swf"); It has no switches, though, as far as I could find. It also goes fullscreen by sending Ctrl+F, so you shouldn't need all the title bar/border removing.

I noticed your script is for version 10. Version 11 is out and you can get it here: http://www.adobe.com/support/flashplayer/downloads.html. It shouldn't affect your script, but I know that some newer games won't play on 10.

All of that was in there already before I got to the script so I decided to leave it in there. I'll look into the version 11 changes and update if needed.

[gamesmame]

Not work for me no open in fullscreen

[zerojay]

I'm going to need far more information than that to help fix it. What is actually going on? Do you have QRes.exe in the right place?

[Lailoken]

It also goes fullscreen by sending Ctrl+F, so you shouldn't need all the title bar/border removing.

I was wrong about this part. The border removing bit was for if you're not using fullscreen. This does take care of a problem I've noticed with certain flash games. Some of them were designed to have a specific window ratio and if you go outside of that then you'll see things you weren't meant to (e.g. on Abobo's Big Adventure loading screen you see his disembodied arm float in from the side if you're full screen). I've been toying with ways to fix this in my script, but every thing I've tried ends up being too complicated.

The drawback to the method in this script is that the window size is not increased at all, so if the original game is tiny then you will have a tiny window centered on your screen.

It did give me some ideas, though. I'm going to experiment with them and post my flash modules later.

[zerojay]

The drawback to the method in this script is that the window size is not increased at all, so if the original game is tiny then you will have a tiny window centered on your screen.

And that's why I change the screen resolution to match the game so that the tiny window ends up filling your screen.

[Lailoken]

And that's why I change the screen resolution to match the game so that the tiny window ends up filling your screen.

Yeah, sorry. I was thinking one thing and typing another (I do that). The issue I had with it was that cutting off the border solved the problem I described in my previous post, but that didn't help with games that were scalable. For instance, if you wanted to keep the borders hidden on Abobo's Big Adventure, but wanted it to be as big as it could be.

I modified what you had so that it makes the game as large as possible (with normal resolution) while keeping its original ratio, and therefore hiding the borders.

One of the things I was using in my script was turning on the "Show All" option, which made changing resolutions unnecessary, but then I noticed that certain games were somewhat CPU intensive after turning on Show All and going fullscreen.

I keep running into isolated problems with 1 or 2 of the games I test and end up having to edit part or all of my module.

[gamesmame]

zerojay in your module you use hyperlaunch "YES" or "NO"???

[brolly]

zerojay in your module you use hyperlaunch "YES" or "NO"???

uh?? What would be the point on doing a module if you had hyperlaunch set to no?

[Lailoken]

I think I've finally got my script to a usable point. It's become a bit of a monster due to all the different things I've added to attempt to run each game in the best quality.

Most of this is in the notes, but I'll explain the different options in the Settings.ini:

Fullscreen (true/false) - If true then FlashPlayer's fullscreen mode is turned on. If false then it will use a pseudo-fullscreen mode that hides unwanted borders. Here's an example of an unwanted border in a flash game.

Resolution (widthxheight[@refresh]) - If your display must be resized you can add in a new resolution here by putting in the width, height and refresh rate (optional). For example 640x480@60, 800x600 or 1280x720.

HideMouse (true/false) - If true then this will hide your mouse cursor after it has been idle for a specified number of seconds (specified at the top of the Settings.ini file as IdleTime). So, if set to true and IdleTime = 5 then if your mouse has been idle for 5 seconds it will disappear. The cursor will reappear once you move your mouse.

Delay (#) - The delay is used to hide the program screen for a specified number of seconds while the game loads. This was necessary for a few games I tested because intro videos or ads that played at the start would break the fullscreen. You could also just use it to hide the advertisements at the start of games if you'd like. Master volume is muted during the delay.

On first run it will create the Settings.ini and on each game's first run it will create an entry for that game with default settings. You'll have to go in to Settings.ini and tweak where needed.

For the resolution change I used Display Changer, which can be downloaded here. Just make sure that you put dc.exe in the module folder.

I've tested dozens of games, but let me know if anyone who uses this encounters any specific issues.

;------------------------------------------------------------------------
; Flash
; FlashPlayer v11
; by Lailoken (with parts shamelessly stolen from djvj and zerojay)
; 1.0
;
; Notes:
; This script uses Adobe Flash Player and Display Changer. There is also a Settings.ini which should be
; in the same folder as this module. Settings.ini will be created on the first run and each game entry 
; will be automatically added with default settings on each game's first run. The settings will need to 
; be adjusted manually to suit each game. 
;
; There are 4 options that can be adjusted:
; 1. Fullscreen - If true then the fullscreen feature in Flash Player will be turned on. If false it will
;	create a pseudo-fullscreen mode which will take up the entire screen, but borders will be hidden. 
; 2. Resolution - If you cannot run the game in fullscreen under normal display resolution you can insert
;	a new resolution here. The resolution will be changed when the program starts and revert back when
;	the program closes. Syntax is widthxheight[@refresh] (e.g. 640x480@60). Refresh is optional.
; 3. HideMouse - If true then your mouse curser will be hidden if idle for a specified number of seconds
;	and reappear when the mouse cursor is moved again. The number of seconds is specified by IdleTime
;	at the top of Settings.ini
; 4. Delay - The delay is the number of seconds in which a loading screen will show while the game is 
;	queuing up in the background. Some games have intro videos or advertisements which break the 
;	fullscreen feature unless a delay is added. 
;
; The default settings will play the games in fullscreen, under normal resolution with HideMouse turned off
; and a 0 second delay.
;------------------------------------------------------------------------

DisplayChanger := CheckFile(A_ScriptDir . "\Modules\" . systemName . "\dc.exe")
settingsFile := CheckFile2(A_ScriptDir . "\Modules\" . systemName . "\Settings.ini")

IniRead, fullscreen, %settingsFile%, %romName%, Fullscreen

If (fullscreen = "ERROR")
fullscreen := CreateSection(settingsFile, romName)

IniRead, idletime, %settingsFile%, Settings, IdleTime, 0
IniRead, hidemouse, %settingsFile%, %romName%, HideMouse, false
IniRead, resolution, %settingsFile%, %romName%, Resolution, 
IniRead, delay, %settingsFile%, %romName%, Delay, 0

fullscreen := %fullscreen%	;convert to boolean
hidemouse := %hidemouse%	;convert to boolean
idletime := idletime * 1000	;convert to milliseconds
delay := delay * 1000		;convert to milliseconds
StringSplit, res_array, resolution, x@	;convert to array

Gui, 1:Color, 000000
Gui, 1:-Caption +ToolWindow +AlwaysOnTop
Gui, 1:Font, s36,
Gui, 1:Add, Text, cWhite w%A_ScreenWidth% h%A_ScreenHeight% 0x200 Center, Loading...
Gui, 1:Show, x0 y0 w%A_ScreenWidth% h%A_ScreenHeight% , LoadScreen

if Not (fullscreen) 
{
WinMinimizeAll
Gui, 2:Color, 000000
Gui 2:-Caption +ToolWindow
Gui, 2:Show, x0 y0 w%A_ScreenWidth% h%A_ScreenHeight%, BlackScreen
WinSet, ExStyle, +0x08000000L, BlackScreen	;makes the GUI not clickable
}

If (res_array1)
{
if (res_array3)
	parameters = -width=%res_array1% -height=%res_array2% -refresh=%res_array3%

Else
	parameters = -width=%res_array1% -height=%res_array2%


Run, %DisplayChanger% %parameters% "%emuPath%%Executable%" "%romPath%%romName%%romExtension%"
}
Else
Run, %executable% "%romPath%%romName%%romExtension%", %emuPath%

WinWait, AHK_class ShockwaveFlash, , 5

WinActivate, LoadScreen

If (ErrorLevel)
Goto, EndProcess

WinActivate, AHK_class ShockwaveFlash

Send {Volume_Mute}	;mute sound while loading

Sleep, %delay%

WinMenuSelectItem, AHK_class ShockwaveFlash, , View, Show All	;set to Show All

Send ^h		;set to High Quality

If (fullscreen)
Send ^f
Else
ExpandWindow("AHK_class ShockwaveFlash")

Gui, 1:Destroy		;destroy LoadScreen

Send {Volume_Mute}	;unmute sound

If (hidemouse) 
{
lastmove := A_TickCount
mousevisible := true
SetTimer MouseCheck, 1
}

Process, WaitClose, %executable%

EndProcess:

WinActivate, Hyperspin

ExitApp

;----------------------------------------------------------------------------
; Functions
;----------------------------------------------------------------------------

CreateSection(file,sectionname) 
{
FileAppend,`n[%sectionname%]`nFullscreen=true`nResolution=`nHideMouse=false`nDelay=0`n, %file%
Return "true"
}

CheckFile2(file) 
{
IfNotExist, %file%
{
	MsgBox, 48, Error, Cannot find %file%.`nA default Settings.ini has been created. Open it to edit your game options., 8
	FileAppend, [settings]`nIdleTime=5`n, %file%
}
Return %file%
}

ExpandWindow(title) 
{
WinSet, Style, -0xC00000, %title% 	;Removes the titlebar of the game window
WinSet, Style, -0x40000, %title% 	;Removes the border of the game window
DllCall("SetMenu", uint, WinExist(title), uint, 0) 	;Removes the MenuBar

WinGetPos, x, y, width, height, %title%
width := width - 16	;change width to actual Flash dimensions
height := height - 58	;change height to actual Flash dimensions

If (width/height > A_ScreenWidth/A_ScreenHeight)	;for games with wider ratio than your monitor
{
	h := ( A_ScreenWidth / width ) * height
	w := A_ScreenWidth
	x := 0
	y := ( A_ScreenHeight / 2 ) - ( h / 2 )
}
Else
{
	h := A_ScreenHeight
	w := (A_ScreenHeight / height) * Width
	x := ( A_ScreenWidth / 2 ) - ( w / 2 )
	y := 0 
}
WinMove, %title%, , x, y, w, h
}

SystemCursor(OnOff=1)	;INIT = "I","Init"; OFF = 0,"Off"; TOGGLE = -1,"T","Toggle"; ON = others
{  
   static AndMask, XorMask, $, h_cursor
       ,c0,c1,c2,c3,c4,c5,c6,c7,c8,c9,c10,c11,c12,c13 ;system cursors
       , b1,b2,b3,b4,b5,b6,b7,b8,b9,b10,b11,b12,b13   ;blank cursors
       , h1,h2,h3,h4,h5,h6,h7,h8,h9,h10,h11,h12,h13   ;handles of default cursors
   if (OnOff = "Init" or OnOff = "I" or $ = "")       ;init when requested or at first call
   {
       $ = h                                          ;active default cursors
       VarSetCapacity( h_cursor,4444, 1 )
       VarSetCapacity( AndMask, 32*4, 0xFF )
       VarSetCapacity( XorMask, 32*4, 0 )
       system_cursors = 32512,32513,32514,32515,32516,32642,32643,32644,32645,32646,32648,32649,32650
       StringSplit c, system_cursors, `,
       Loop %c0%
       {
           h_cursor   := DllCall( "LoadCursor", "uint",0, "uint",c%A_Index% )
           h%A_Index% := DllCall( "CopyImage",  "uint",h_cursor, "uint",2, "int",0, "int",0, "uint",0 )
           b%A_Index% := DllCall("CreateCursor","uint",0, "int",0, "int",0
               , "int",32, "int",32, "uint",&AndMask, "uint",&XorMask )
       }
   }
   if (OnOff = 0 or OnOff = "Off" or $ = "h" and (OnOff < 0 or OnOff = "Toggle" or OnOff = "T"))
       $ = b  ; use blank cursors
   else
       $ = h  ; use the saved cursors

   Loop %c0%
   {
       h_cursor := DllCall( "CopyImage", "uint",%$%%A_Index%, "uint",2, "int",0, "int",0, "uint",0 )
       DllCall( "SetSystemCursor", "uint",h_cursor, "uint",c%A_Index% )
   }
}

MouseCheck:
MouseGetPos, Mouse_x, Mouse_y
If (Mouse_x != Last_x || Mouse_y != Last_y) 
{
	If Not (mousevisible) 
	{
		SystemCursor("On")
		mousevisible := true
	}
	lastmove := A_TickCount
}
Else If (A_TickCount > lastmove + idletime && mousevisible) 
{
	SystemCursor("Off")
	mousevisible := false
}
Last_x := Mouse_x
Last_y := Mouse_y
Return

CloseProcess:
WinClose, AHK_class ShockwaveFlash
Gui, 2:Destroy		;destroy BlackScreen
SystemCursor("On")
WinMinimizeAllUndo

Return

[zerojay]

I originally was using display changer, but the program has some bugs that were causing me major issues. It would refuse to do 800x600, for instance.

[Lailoken]

I originally was using display changer, but the program has some bugs that were causing me major issues. It would refuse to do 800x600, for instance.

I can't say for sure since I don't know what your setup is, but for me that problem has to do with refresh rate. My normal display mode is 1680 x 1050 at 59 hertz and 800 x 600 is only possible at 60 hertz. If you don't tell it to change the refresh rate then it will cause an error because 800 x 600 at 59 hertz is an unsupported mode.

After I realized that I haven't had any issues with Display Changer. I chose it over QRes simply because DC automatically switches back to your normal resolution when the program exits or even if the script fails.

Honestly, though, I don't like having to change my resolution at all unless absolutely necessary. The majority of my games play fullscreen just fine, but a few of them are CPU intensive so I have to reduce the resolution or it uses like 80% of my CPU on its own.

[gamesmame]

zerojay and Lailoken

Look, please help me to fix...

http://www.youtube.com/watch?v=Dr45aQ7-608

Wy not Work in fullscreen???

[Lailoken]

You have it set to PC game, so it doesn't look like you're running it through a module. Try these settings:

[exe info]
path=M:\Emulators\Flash Games\
rompath=M:\Emulators\Flash Games\
userompath=
exe=flashplayer_11.exe
romextension=swf
parameters=
searchsubfolders=true
pcgame=false
winstate=NORMAL
hyperlaunch=true

[gamesmame]

You have it set to PC game, so it doesn't look like you're running it through a module. Try these settings:

[exe info]
path=M:\Emulators\Flash Games\
rompath=M:\Emulators\Flash Games\
userompath=
exe=flashplayer_11.exe
romextension=swf
parameters=
searchsubfolders=true
pcgame=false
winstate=NORMAL
hyperlaunch=true

I tried the settings that a friend Lailoken gave me...

And gave this error:

[gamesmame]

Heuhauhahuauh... Sorry Lailoken i am going crazy, i deleted the line 260... and work perfect!! thank you!!!

Too bad we have to click the mouse in Abobo game to work, have a way to make the script give this mouse click to start game Abobo?